{
  alsa-lib,
  autoPatchelfHook,
  copyDesktopItems,
  fetchurl,
  fontconfig,
  gcc,
  iconConvTools,
  icu,
  lib,
  libusb1,
  makeDesktopItem,
  stdenv,
  util-linux,
  xorg
}:

let

  hash = "83273bcd8";

  platforms = {
    aarch64-linux = {
      arch = "arm64";
      sha256 = "3e22926dcfbb85f27e1a42e53368d6794b83fbede114707fa4fedf053984323d";
    };

    x86_64-linux = {
      arch = "x64";
      sha256 = "81e94b31f6cd8699c51aa3f5742ce42dd4f3dbc94ce9d72d25c6e8a5851db664";
    };
  };

  version = "1.0.4";

  inherit (stdenv.hostPlatform) system;

in

  with platforms.${system} or (throw "Unsupported system: ${system}");

  stdenv.mkDerivation rec {
    inherit version;
    pname = "sdrconnect";

    src = fetchurl {
      url = "https://www.sdrplay.com/software/SDRconnect_linux-${arch}_${hash}.run";
      inherit sha256;
    };

    nativeBuildInputs = [ autoPatchelfHook copyDesktopItems iconConvTools ];

    buildInputs = [
      alsa-lib
      fontconfig
      libusb1
      util-linux # for libuuid
      gcc.cc.lib # for libstdc++
    ];

    runtimeDependencies = [
      icu
      xorg.libX11
      xorg.libICE
      xorg.libSM
    ];

    appendRunpaths = [ "${placeholder "out"}/lib" ];

    unpackPhase = ''
      bash $src --target . --noexec
    '';

    postInstall = ''
      mkdir -p $out/bin $out/lib
      cp SDRconnect $out/bin
      cp *.so $out/lib
      icoFileToHiColorTheme sdrconnect.ico sdrconnect $out
    '';

    desktopItems = with meta; [
      (makeDesktopItem {
        name = pname;
        icon = pname;
        exec = mainProgram;
        comment = description;
        desktopName = "SDRconnect";
        genericName = "SDRplay Client";
        categories = [ "Audio" "HamRadio" ];
        keywords = [ "Ham" "Radio" "SDR" ];
      })
    ];

    meta = with lib; {
      description = "Cross platform GUI client for SDRplay";
      homepage = "https://www.sdrplay.com/sdrconnect/";
      sourceProvenance = with sourceTypes; [ binaryNativeCode ];
      license = licenses.unfree;
      platforms = attrNames platforms;
      mainProgram = "SDRconnect";
    };
  }